#!/usr/bin/awk -f

function realtime (t) {
  
  sub(/:[0-9][0-9]?$/, ":&", t);
  s = (t ~ /:[0-9]$/) ? ".0" : ".";
  sub(/::/, s, t);

  split(t, artime, /:/);

  rt = 0;
  for (i in artime) rt = rt * 60 + artime[i];

  return rt;
}

function printtime (rt) {
  f = sprintf("%.2f", rt);
  sub(/^.*\./, "", f);
  t = sprintf("%02d:%s", int(rt % 60), f);
  for (i=1; i<3; i++) {
    rt = int (rt / 60);
    temp = rt % 60;
    t = sprintf("%02d:%s", temp, t);
  }
  return t;
}

BEGIN {
  if ((ARGC < 3) || (ARGC > 4)) {
    printf "Usage: SubViewerSplit.awk <time> <input> [output]\n" \
      >> "/dev/stderr";
    printf " time: median time ([+-]HH:MM:SS:mm)\n" >> "/dev/stderr";
    exit(-1);
  }

  output1 = (ARGC == 4) ? ARGV[3] ".1" : ARGV[2] ".1";
  output2 = (ARGC == 4) ? ARGV[3] ".2" : ARGV[2] ".2";
  printf "" > output1;
  printf "" > output2;
  
  time = realtime(ARGV[1]);
  
  ARGV[3] = ARGV[1] = "";
  header = 1;
  file = "1";
}

# For dos and mac
{
  sub(/\r/, "", $0);
  sub(/\f/, "", $0);
}

$1 == "{T" && $2 ~ /[0-9][0-9]:[0-9][0-9]:[0-9][0-9]:[0-9][0-9]/ {

  header = 0;

  beg = realtime($2);

  file = (time > beg) ? "1" : "2";

  $2 = printtime((time > beg) ? beg : beg - time);
}

{
  if ((file ~ /1/) || (header == 1)) {
    printf "%s\n", $0 >> output1;
  }
  if ((file ~ /2/) || (header == 1)) {
    printf "%s\n", $0 >> output2;
  }
}