#!/usr/bin/awk -f

function realtime (t) {
  sub(/,/, ".", t);
  split(t, artime, /:/);

  rt = 0;
  for (i in artime) rt = rt * 60 + artime[i];

  return rt;
}

function printtime (rt) {
  f = sprintf("%.3f", rt); 
  sub(/^.*\./, "", f);
  t = sprintf("%02d.%s", int(rt % 60), f);
  for (i=1; i<3; i++) {
    rt = int (rt / 60);
    temp = rt % 60;
    t = sprintf("%02d:%s", temp, t);
  }

  sub(/\./, ",", t);

  return t;
}

BEGIN {
  if ((ARGC < 3) || (ARGC > 4)) {
    printf "Usage: SubRipperSplit.awk <time> <input> [output]\n" \
      >> "/dev/stderr";
    printf " time: median time ([+-]HH:MM:SS.mmm)\n" >> "/dev/stderr";
    exit(-1);
  }

  output1 = (ARGC == 4) ? ARGV[3] ".1" : ARGV[2] ".1";
  output2 = (ARGC == 4) ? ARGV[3] ".2" : ARGV[2] ".2";
  printf "" > output1;
  printf "" > output2;

  time = realtime(ARGV[1]);

  ARGV[3] = ARGV[1] = "";

  ind = 0;
  nextind = 1;
  file = "1";
}

# For dos and mac
{
  sub(/\r/, "", $0);
  sub(/\f/, "", $0);
}

NF == 0 {
  nextind = 1;
}

$1 ~ /\<[0-9]+\>/ {
  if (nextind) $0 = "";
  nextind = 0;
}

$2 == "-->" {
  beg = realtime($1);
  end = realtime($3);

  nfile = (time > end) ? "1" : ((time > beg) ? "12" : "2");
  if ((file == "1") && (nfile != file)) {
    indend1 = ind;
  }
  file = nfile;

  if ((file ~ /1/) && (ind != 0)) {
    printf "\n" >> output1;
  }

  if ((file ~ /2/) && (ind != indend1)) {
    printf "\n" >> output2;
  }

  ind++;

  if (file == "1") {
    printf "%d\n%s --> %s\n", ind, printtime(beg), printtime(end) \
      >> output1;
  } else if (file == "2") {
    printf "%d\n%s --> %s\n", ind - indend1, printtime(beg - time), \
      printtime(end - time) >> output2;
  } else {
    printf "%d\n%s --> %s\n", ind, printtime(beg), printtime(time) \
      >> output1;
    printf "%d\n%s --> %s\n", ind - indend1, printtime(0), \
      printtime(end - time) >> output2;
  }

  $0 = "";
}

NF > 0 {
  if (index(file, "1") != 0) {
    printf "%s\n", $0 >> output1;
  }
  if (index(file, "2") != 0) {
    printf "%s\n", $0 >> output2;
  }
}